import tasks.ReportGenerateTask

plugins {
	id 'java-library'
	id 'org.jetbrains.kotlin.jvm'
	id 'com.google.devtools.ksp'
	id 'maven-publish'
}

group = 'org.koitharu'
version = '1.0'

test {
	useJUnitPlatform()
}

compileKotlin {
	kotlinOptions {
		jvmTarget = '1.8'
		freeCompilerArgs += [
				'-opt-in=kotlin.RequiresOptIn',
				'-opt-in=kotlin.contracts.ExperimentalContracts',
				'-opt-in=org.koitharu.kotatsu.parsers.InternalParsersApi',
		]
	}
}

compileTestKotlin {
	kotlinOptions {
		jvmTarget = '1.8'
		freeCompilerArgs += [
				'-opt-in=kotlin.RequiresOptIn',
				'-opt-in=kotlinx.coroutines.ExperimentalCoroutinesApi',
				'-opt-in=org.koitharu.kotatsu.parsers.InternalParsersApi',
		]
	}
}

kotlin {
	sourceSets {
		main.kotlin.srcDirs += 'build/generated/ksp/main/kotlin'
	}
}

afterEvaluate {
	publishing {
		publications {
			mavenJava(MavenPublication) {
				from components.java
			}
		}
	}
}

dependencies {
	implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.6.4'
	implementation 'com.squareup.okhttp3:okhttp:4.10.0'
	implementation 'com.squareup.okio:okio:3.2.0'
	implementation 'org.jsoup:jsoup:1.15.2'
	implementation 'org.json:json:20220320'
	implementation 'androidx.collection:collection-ktx:1.2.0'

	ksp project(':kotatsu-parsers-ksp')

	testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
	testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
	testImplementation 'org.junit.jupiter:junit-jupiter-params:5.8.2'
	testImplementation 'org.jetbrains.kotlinx:kotlinx-coroutines-test:1.6.4'
	testImplementation 'io.webfolder:quickjs:1.1.0'
}

task generateTestsReport(type: ReportGenerateTask)